[noobatns]

Hey, I've got a fairly basic (I hope) AppleScript that I'd like to write.

I need to get the current filename from the active SubEthaEdit window, and then I need to javac that file, while displaying the results... preferrably in a new SubEthaEdit document.


This functionality would be similar to the compile java function in textpad (www.textpad.com)

Ok, so anyone dare to try and help me out here? I really don't know what to do, and I can't get much of any applescript to work, I keep getting errors.. but I think it's because I don't know much AppleScript, and it confuses me...

[Diggory Laycock]

I knocked something up:

- Annoyingly SubEthaEdit does not seem to allow you to make new documents with text in - or set the text of documents, so I had to use TextEdit for the result.

[edit - tweaked to be slightly nicer.]

Code:
--	Java Compilation Routine
on compileMyJava(sourcePath)
	try
		set compileResult to (do shell script "javac " & sourcePath)
	on error someError
		set compileResult to someError
	end try
	return compileResult
end compileMyJava




tell application "SubEthaEdit"
	if (number of windows) < 1 then
		display dialog "There are no open subEthaEdit windows." buttons {"OK"} giving up after 1 -- seconds
		return -- can't compile nothing!
	else
		set frontDoc to text document of front window
		
		if modified of frontDoc is true then
			set saveReply to display dialog "There are Unsaved Changes!  Do you want to Save the source?  (choosing 'No' will cancel compilation.)" buttons {"No", "Yes"} default button 2
			if button returned of saveReply is "No" then
				return
			else
				save frontDoc
			end if
		end if
		
		try
			set theSourcePath to path of frontDoc
			--			display dialog "path: " & theSourcePath
		on error errorString number errorNumber
			display dialog "This Document has never been saved to a file- It cannot be Compiled."
			return
		end try
		
	end if
end tell

set compileResult to compileMyJava(theSourcePath)

if compileResult is equal to "" then
	say "Source compiled with no errors." --	You can comment out either of these lines.
	display dialog "No Errors - Your source is now compiled." buttons "OK" default button 1 giving up after 10 --	You can comment out either of these lines.
else
	tell application "TextEdit"
		activate
		set resultsDoc to make new document at front
		set the name of window 1 to "Java Compile results"
		set the text of resultsDoc to compileResult -- Spit out the compilation error
	end tell
end if

[Diggory Laycock]

Oh yes - don't forget to put the script into ~/Library/Scripts/Applications/SubEthaEdit/

Then you can call the script from the Script Menu (When you are in SubEthaEdit - it hides it otherwise)