Anyone know how to set your monitor to grayscale. I know you can use 'set monitor depth 8' to set it to 8 bit, but it is in color.

Any idea's?

Thanks,

Chuck

[Paul Crawford]

Hi,

I'm not certain, but I don't think that Apple's standard 'MonitorDepth' scripting additon allows you to switch a monitor's color/gray mode. However, there is at least one available third-party scripting addition (Jon’s Commands) that would let you do so.

Below is some sample code that can force the main (menu-bar) monitor or any desired monitor to use 8-bit grays:-

Code:
-- -----------------------------------------------------------------------------------------------------
-- // NOTE: This script requires the 'Jon’s Commands' OSAX
on run
	try
		-- First, retrieve the list of information-records for all monitors 
		-- (preferably with the one for the main monitor placed at the head of the list)
		set theMonitorInfoRecords to (screen list starting with main screen)
	
		-- Next, set up the desired monitor(s) to use 8-bit grays
		repeat with thisMonitorInfoRecordRef in theMonitorInfoRecords
			-- Check whether this monitor is suitable  (OPTIONAL)
			-- [This sample just checks for the main monitor and simply assumes it's 8-bit—capable]
			if (has menu bar of thisMonitorInfoRecordRef) then -- It's the main monitor
				-- Specify that this monitor is now to use 8-bit colors/grays…
				set the color depth of thisMonitorInfoRecordRef to 8
				-- …and then specify that it is now to be in grayscale mode
				set the in color of thisMonitorInfoRecordRef to false
				-- [Abort the loop, if just this one monitor is to be changed]
				exit repeat
			end if
		end repeat
	
		-- Finally, apply any changes that were made to the monitor information-record(s) above
		set screens to theMonitorInfoRecords

	on error errMsg number errNum
		-- Hopefully, the monitor isn't screwed up too badly, and this error-dialog can be seen!
		display dialog ("Sorry, the monitor adjustment failed!" & return & return & "(" & errNum & ") " & errMsg) ¬
			buttons {"Stop"} default button 1 with icon stop
	end try
	
	return
end run

If you prefer not to use any third-party scripting additions, someone else may be able to provide a "native" solution that requires only pure AppleScript or official Apple scripting additions.

Regards,

--Paul

[This message has been edited by Paul Crawford (edited 07-11-2000).]

Thanks for the info. Sadly, I need a solution for a standard mac set scripting additions.

Anyone else with an idea?

Chuck