Welcome to the MacNN Forums.

ameat · Feb 4, 2002, 06:05 AM

hey there

i know that this is what project builder is meant for but since i'm used to bbedit, i prefer to code there...

anyway, i'm taking a university course in C and have been writing my source in bbedit and then working in the terminal to compile the program, change its file name and then execute the program...this was tedious at first but i've since gotten a little more unix savvy learning about command history and such. however, this is even getting tedious for instance if i make a bunch of little quick changes trying to see what happens (i'm used to web based, interpretted languages).

anyway, i was wondering if there's a way i can create a quick apple script or shell script that i can stick in the bbedit script menu that'll simply input these commands:

<BLOCKQUOTE>code:<HR><pre>
>cc filename.c // where filename is automatically extracted
>mv a.out filename
>./filename
[/code]

then, selecting the script compiles the sucker and exectues it for me...

so if there are any suggestions, or solutions, it's much appreciated,
thanks

amit

Arakageeta256 · Feb 4, 2002, 11:02 AM

...kinda reminds me of emacs actually. I've always thought of BBEdit as Emacs for the Mac and wondered why it didn't do this (or at least make it obvious).

z0mbi3 · Feb 6, 2002, 12:42 AM

hum...meybe you'll be happier to know that you don't need to make that 'mv' command if you do something like 'cc source.c -o filename'
try it

you can even make a script called run.sh that compiles everything and runs it...it's not that hard.

Paul McCann · Feb 6, 2002, 01:27 AM

OK, here's a rust-riddled attempt at producing something like a script to do what you requested from BBEdit. Saving it as a compiled script in BBEdit's scripts folder is probably the easiest way to access it from that editor: you might want to assign a keyboard shortcut as well.

A couple of things to watch for: as per the comment at the head of the script, your executable's return value has to be 0 for the "do shell script" command to succeed. At least that's my reading of the situation. "display dialog" might not be appropriate, depending on the size of the output that you're seeing. If you need acres of display space you might want to open a new bbedit window with that content.

Anyway, hope this at least gives you some ideas.

Cheers,
Paul

<BLOCKQUOTE>code:<HR><pre>
(* If the frontmost bbedit window is called "something.c" and has been saved as
/path/to/source/something.c then this script should compile it using
"cc -o /path/to/source/something /path/to/source/something.c" and then run it via
"/path/to/source/something". Things to watch for: your executable should exit
cleanly, or you'll get the same "execution error" output from "do shell script"
that plagued me while writing what's below. Looks like that command just groans
when it sees anything other than an exit status of 0. *)

tell application "BBEdit 6.5"
set open_filename to the name of window 1 -- filename of the frontmost file in bbedit
if ((text items -2 thru -1 of open_filename) as text) is not ".c" then
tell me to activate
display dialog "Sorry, not a .c file"
return
else if (modified of window 1) then
activate
set save_flag to display dialog "Save your work first, then compile!" buttons {"Cancel", "Save"} default button "Save"
if button returned of save_flag is "Save" then
save window 1
else
return
end if
end if
set bare_name to (text items 1 thru -3 of open_filename) as text --ie, without suffix
set assoc_file to POSIX path of ((file of window 1) as text) -- unix-style path to file
my shellit(open_filename, bare_name, assoc_file)
end tell

on shellit(source_file, output_file, path_to_source)
set working_dir to my parentdir(path_to_source)
set compile_command to "cc -o " & working_dir & "/" & output_file & " " & working_dir & "/" & source_file
set run_command to working_dir & "/" & output_file
set shelloutput to do shell script compile_command
set shelloutput to do shell script run_command
activate
display dialog "\"" & output_file & "\" produced the following output:" & return & shelloutput
end shellit

on parentdir(unix_filepath)
set olddelims to AppleScript's text item delimiters
set AppleScript's text item delimiters to "/"
set path_to_dir to (text items 1 thru -2 of unix_filepath) as text
set AppleScript's text item delimiters to olddelims
return path_to_dir
end parentdir
[/code]

[ 02-06-2002: Message edited by: Paul McCann ]

ameat · Feb 6, 2002, 05:22 AM

Originally posted by z0mbi3:
hum...meybe you'll be happier to know that you don't need to make that 'mv' command if you do something like 'cc source.c -o filename'
try it

you can even make a script called run.sh that compiles everything and runs it...it's not that hard.

well, that helps some...and paul, thanks for the applescript, i'll be trying that shortly once i completely understand what's going on that script...despite applescripts desire to sound more like english, i find it even more foreign looking than actual code.

anyway, thanks for your help...

amit

benh57 · Feb 7, 2002, 03:03 PM

There's no reason why you can't edit the file in BBEdit, and compile/run/debug with project builder at the same time. PB will know that you changed the file. No fancy scripts required.