[vexingv]

ive been a pc-only user but got a powerbook in May and i'm using it these days to get my work done (less distractions). questions:

on the pc, i could edit excel cells by pressing F2 first so that i didnt overwrite the cell. how do i do this on the mac version? (aside from doubleclicking on the cell, which is not as fast).

how do i set a default zoom other than 100%? the text is tiny on my 12" pb that i need it to at least 150%. on word i set it to 200% and the setting stays after exit, open new doc, etc, but not in excel.

thanks.

[Mithras]

Googling Excel F2 got me this useful page, which says:

In WinXL, pressing the function key F2 enters Edit Mode in the active cell. For Macs, the corresponding keyboard shortcut is CTRL-u. (On at least some Extended Keyboards, pressing the keypad's Clear/Num Lock will clear the cell and enter Edit Mode.) Since some enlightened (i.e., former) WinXL users want F2 to do the same thing on the Mac that it does in Windows, this procedure will accomplish that.

If you don't have a Personal Macro Workbook (PMW) started yet, choose Tools/Macro/Record new macro, choose PMW from the location dropdown and record something - selecting cells, etc. - then click the stop button.

Type Opt-F11 to enter the Visual Basic Editor. Select the Personal Macro Workbook item from the Project Browser window. Double click it to see a folder marked Microsoft Excel Objects. Open that folder and double click the ThisWorkbook icon, which opens up the ThisWorkbook code module. Paste the following into that window:

Private Sub Workbook_Open()
Application.OnKey "{F2}", "F2Edit"
End Sub

Choose Insert/Module and paste this into the window that opens. Note that the control ID changed with XL2004.

Public Sub F2Edit()
Dim nF2 as Long
nF2 = IIf(Application.Version < 11, 6034&, 8217&)
CommandBars.FindControl(Id:=nF2).Execute
Application.OnKey "{F2}", "F2Edit"
End Sub

Save the PMW (File/Save PMW) and type Opt-F11 to return to XL. Quit XL and restart - F2 will now work to enter Edit Mode.

and googling excel "default zoom" yields this little tip, which also requires a little macro writing:

In my startup add-in, I have a class module, "MyWindowClass" with the
following code (among other events):

Public WithEvents oApp As Application

Private Sub oApp_WorkbookOpen(ByVal Wb As Excel.Workbook)
With ActiveWindow
.Top = 1
.Left = 1
.Zoom = 100
End With
End Sub

Private Sub Class_Initialize()
Set oApp = Application
End Sub

with this in a regular code module:

Dim clsMyWindow As MyWindowClass

Public Sub Setup_Windows()
Set clsMyWindow = New MyWindowClass
End Sub

and in the ThisWorkbook code module:

Private Sub Workbook_Open()
Setup_Windows
End Sub

This sets the windows of all workbooks that open after the startup
add-in to open in the upper left corner, with a zoom of 100%. Change the
zoom to suit.

[vexingv]

thanks for the links/info. i thought there had to be something easier, since the F2 edit proved to be so useful. i hate macros (pc or mac). i'll bookmark this for later, but crtl-u and manually setting zoom will have to do for now.

[5by5]

How rare!! My search found a topic that covered exactly what I was looking for!

The only problem is the listed solution doesn't work for me.

Has anyone else tried this and succeeded?

5by5