[RealMadrid]

Hi,

some time ago I read a question about the possibility of remote controlling MacOS X via Bluetooth phone.

Now over at the AI fora I found a post related to that.

http://forums.appleinsider.com/cgi-b...8&t=000629

It´s great! Thanks to the original poster and the developer.

Regards.

[kovacs]

Yeah just found it one versiontracker and it's awesome !

[iDriveX]

Being the hugely skeptical person that I am, I downloaded it, thinking that it would be this long drawn out process and would be more of a hassle than anything else.

Dear God, you'd think Apple had made this. It's a simple pref pane. Select the device in the pref pane, click Publish. And boom, you have a menu on your T68i that lets you control iTunes (as well as other apps). How great is this? AND it doesn't interfere with other apps like iSync or Address Book! You SHOULD download this if you have a T68i and a Bluetooth reciever.

[mitchell_pgh]

What else can you do with it?

iTunes is cool, but what else can you work with...

(wow, doesn't this open up a world of things?)

with home automation, you can now do just about anything from your phone ;-)

[::maroma::]

Originally posted by mitchell_pgh:
What else can you do with it?

iTunes is cool, but what else can you work with...

(wow, doesn't this open up a world of things?)

with home automation, you can now do just about anything from your phone ;-)

It's AppleScript-able so just about anything can be done with it. Hopefully, this guy's web site will host a bunch of user scripts for all to enjoy.

[jahpaul]

this rocksjavascript:smilie('')

[sja777]

This is the best software I've downloaded since ... oh, I can't think ...

But this beta expires on 1 March 2003. I hope this isn't just a few days fun ...

[iDriveX]

I think this will eventually be a shareware program. I would be more than happy to pay for this.

[wynn]

my t68i synchs with address book, but when i click on 'select device' in the clicker pref, nothing happens.

any ideas?

the dropdown menu from the bt icon in menubar shows that my phone is paired.

thanks - can't wait try this.

[Waterman]

Dude! This makes me want a t68i so bad.

It would be sweet to have an AppleScript that played a creepy little AIFF when you brought your phone within the proximity range of the computer. I'm hearing Hal from 2001...

"Hello Dave. It's nice to see you again."

This is just a guess... but you know how Apple registered that patent for computers that changed color to give the user visual feedback? Wouldn't it be cool if the computer changed color when you brought a wireless device near it?

I can't think of another reason to want a computer to change color... but I think that particular reason would rock.

[ebisix]

That's amazing what phones can do these days. Nice post.

[Sal]

My thanks to Jonas Salling for making such fun, useful, and powerful software!

Software download on VersionTracker

Here are the iTunes scripts I use with the software. Enjoy!

Code:
-- PLAY
tell application "iTunes"
	play
end tell

-- PAUSE
tell application "iTunes"
	pause
end tell

-- STOP
tell application "iTunes"
	stop
end tell

-- REWIND
tell application "iTunes"
	try
		set this_track to the current track
		get this_track
		set the player position to 0
	on error -- no track is the current track
		beep
	end try
end tell

-- VOLUME DOWN
tell application "iTunes"
	set the volume_setting to the sound volume
	if the volume_setting is greater than 10 then
		set the sound volume to (the volume_setting - 10)
	else if the volume_setting is 0 then
		beep
	else
		set the sound volume to 0
	end if
end tell

-- VOLUME UP
tell application "iTunes"
	set the volume_setting to the sound volume
	if the volume_setting is less than 90 then
		set the sound volume to (the volume_setting + 10)
	else if the volume_setting is 100 then
		beep
	else
		set the sound volume to 100
	end if
end tell

-- PREVIOUS TRACK
tell application "iTunes"
	previous track
end tell

-- NEXT TRACK
tell application "iTunes"
	next track
end tell

-- RANDOM TRACK FROM TOP 25
tell application "iTunes"
	stop
	set this_track to some track of playlist "Top 25 Most Played"
	play this_track
end tell

-- SPEAK THE TITLE OF THE CURRENT TRACK
tell application "iTunes"
	set this_playlist to the name of current playlist
	set this_track to the name of the current track
	set the player_state to the player state
	pause
	delay 1
end tell
say ("The current song, [[emph-]]is " & this_track & ¬
	 ": of playlist: " & this_playlist) as string
delay 1
tell application "iTunes"
	if the player_state is playing then
		play
	end if
end tell

-- PLAY RANDOM TRACK
tell application "iTunes"
	tell source "Library"
		tell playlist "Library"
			set this_track to some track
			play this_track
		end tell
	end tell
end tell

-- ACTIVATE
tell application "iTunes"
	activate
end tell

[jparisi]

I have this problem where if i don not remove the menu from my phone, and I put my computer to sleep, my phone locks up, and I have to remove the battery to start it back up. Is this a problem, or is this just how it works and I have to remember to remove menu before I put my machien to sleep?

[Jordan]

Any chance that the same thing might work on one of the Nokia phones with BlueTooth??? i.e. 6310i

[Amorya]

I'd imagine it's possible to work on a Nokia, but the part of the software that lives on the phone might need to be rewritten. The 6310 does support installing JAVA software, IIRC...

Amorya

[ddma]

Anyone knows how to automatically enter the screen saver password and return by AppleScript? I wanna set it when my notebook detect my phone it'll automatically unlock. I have already set it when my phone is out of range, it automatically activate the screen saver.

[::maroma::]

Originally posted by jparisi:
I have this problem where if i don not remove the menu from my phone, and I put my computer to sleep, my phone locks up, and I have to remove the battery to start it back up. Is this a problem, or is this just how it works and I have to remember to remove menu before I put my machien to sleep?

That's weird, because my phone froze up too the other night. And now that I think about it, it was just after playing with this app for a while. I didn't really put 2 and 2 together before. I think this might be a bug.

[Sal]

Here are a couple additional scripts for Keynote. Since the current version of Keynote is not scriptable, they require the installation of the GUI Scripting support, available from here:

www.apple.com/applescript/GUI/

Code:
-- BLACK
try
	tell application "Keynote"
		activate
	end tell
	tell application "System Events"
		tell process "Keynote"
			keystroke "B" with control down
		end tell
	end tell
on error
	beep
end try


-- STOP
try
	tell application "Keynote"
		activate
	end tell
	tell application "System Events"
		tell process "Keynote"
			keystroke "." with command down
		end tell
	end tell
on error
	beep
end try


-- PLAY
try
	tell application "Keynote"
		activate
	end tell
	tell application "System Events"
		tell process "Keynote"
			tell menu bar 1
				click menu item "Play Slideshow" of menu "View"
			end tell
		end tell
	end tell
on error
	beep
end try

[[osX]RTouris]

Just in case you don't happen to have a SE phone there somewhere, why not see some footage of what this app can do?

http://homepage.mac.com/rtouris/iMovieTheater38.html

[JHromadka]

Originally posted by jparisi:
I have this problem where if i don not remove the menu from my phone, and I put my computer to sleep, my phone locks up, and I have to remove the battery to start it back up.

I held the power button (No button) down for about 5 seconds on my T68i and it went back to the main screen. Try that.

[sandsl]

There are some bugs in this beta release so beware. I've had 2 freezes of my phone, 2 menu item freezes and 1 kernel panic all due to SE Clicker.

That said its a great application and I use it daily.

Its just ashame we're going to have to pay for this soon, when it goes final.

[thePurpleGiant]

EDIT: nevermind

[JB72]

This Jonas Salling seems to have a real hit on his hands. I see raves about this app all over the place already. Good work fella!



The Yahoo! group

I really need to get myself a T68i now.

[Sal]

iPhoto Scripts

Here are more scripts for the Clicker, some of which require the installation of the GUI scripting support located at:

www.apple.com/applescript/GUI/

Use the built-in commands in the Clicker for right arrow and left arrow for next slide and previous slide.

Code:
-- STOP SLIDESHOW
try
	tell application "iPhoto"
		activate
	end tell
	tell application "System Events"
		tell process "iPhoto"
			keystroke "." with control down
		end tell
	end tell
on error
	beep
end try

-- PLAY SLIDESHOW
try
	tell application "iPhoto"
		activate
	end tell
	tell application "System Events"
		tell process "iPhoto"
			-- click the slideshow button
			click button "Slideshow" of list 1 of group 2 of window "iPhoto"
			-- set the slideshow parameters
			tell window "Slideshow Settings"
				-- number of seconds per image
				set the value of text field 1 to "3"
				-- turn off random order
				if value of check box 2 is 1 then click check box 2
				-- turn off repeat
				if value of check box 1 is 1 then click check box 1
				-- turn off music
				if value of check box "Music" of group 1 is 1 then ¬
					click check box "Music" of group 1
				-- play the slideshow
				click button "Play Slideshow"
			end tell
		end tell
	end tell
on error error_message
	beep
end try

-- NEXT ALBUM
try
	tell application "iPhoto"
		activate
		set these_albums to {"Photo Library", "Last Import"} & the name of every album
		set the album_count to the count of these_albums
		set this_name to the name of the current album
		repeat with i from 1 to the album_count
			if item i of these_albums is this_name then
				set this_index to i
				exit repeat
			end if
		end repeat
		if this_index is the album_count then
			set the next_index to 1
		else
			set the next_index to this_index + 1
		end if
		set the next_album to item next_index of these_albums
		if the next_album is "Photo Library" then
			select photo library album
		else if the next_album is "Last Import" then
			select last import album
		else
			select album next_album
		end if
	end tell
	say next_album as string
end try


--- PREVIOUS ALBUM
try
	tell application "iPhoto"
		activate
		set these_albums to {"Photo Library", "Last Import"} & the name of every album
		set the album_count to the count of these_albums
		set this_name to the name of the current album
		repeat with i from 1 to the album_count
			if item i of these_albums is this_name then
				set this_index to i
				exit repeat
			end if
		end repeat
		if this_index is 1 then
			set the next_index to album_count
		else
			set the next_index to this_index - 1
		end if
		set the next_album to item next_index of these_albums
		if the next_album is "Photo Library" then
			select photo library album
		else if the next_album is "Last Import" then
			select last import album
		else
			select album next_album
		end if
	end tell
	say next_album as string
end try

[kman42]

Originally posted by [osX]RTouris:
Just in case you don't happen to have a SE phone there somewhere, why not see some footage of what this app can do?

http://homepage.mac.com/rtouris/iMovieTheater38.html

I can't play your video. QT says it is missing the software to play it. I'm running the latest version of QT though. What's up?

kman

[idjeff]

Originally posted by kman42:
I can't play your video. QT says it is missing the software to play it. I'm running the latest version of QT though. What's up?

kman

Same here.

[Sal]

SCREEN CAPTURE SCRIPT

I made a menu called "System" and added this script for taking a screen capture and saving it into the Pictures folder:

Code:
set the destination_folder to (path to "pdoc")
set the destination_path to POSIX path of the destination_folder
try
	repeat with i from 1 to 10000
		set the file_name to ("screen" & (i as string) & ".pdf")
		alias ((destination_folder as string) & file_name)
	end repeat
on error
	set the target_path to the destination_path & the file_name
end try
do shell script ("screencapture " & target_path)
beep 2

[::maroma::]

Originally posted by kman42:
I can't play your video. QT says it is missing the software to play it. I'm running the latest version of QT though. What's up?

kman

Towards the bottom of the page:

"You need to d/l 3ivx in order to see the video."

There's a link to the software there too.

[Yoda's Erotic Piggyback]

So why does my compter not allow me to drag the pref pane into the PreferencePanes folder?

[RealMadrid]

Originally posted by Yoda's Erotic Piggyback:
So why does my compter not allow me to drag the pref pane into the PreferencePanes folder?

Usually you don't have permissions on the PreferencesPanes folder of /System/Library/. Instead put it ino the PreferencesPanes folder of your account ~/Library/PreferencesPanes.

[Gee4orce]

I just don't see any menu on the phone. Any ideas ? Seems to pair OK (I can Synch normally with it).

[wynn]

Originally posted by Gee4orce:
I just don't see any menu on the phone. Any ideas ? Seems to pair OK (I can Synch normally with it).

did you click 'publish' in the clicker prefs? to get to the menu on the t68i, go to 'connect' -> accessories -> macintosh

[mikerally]

"You need to d/l 3ivx in order to see the video."

Umm, I don't want to install 3ivx, I use mPlayer to play back that sort of stuff, not Quicktime. But I don't seem to have a choice since the 3ivx file is wrapped in a Quicktime *.mov file.

[ymmit]

this would be a really useful app where one can advances slides for powerpoint or keynote using his bluetooth phone.

I might have missed it in the previous postings, but is there a script for moving keynote or powerpoint slides backwards and forwards?

[::maroma::]

Originally posted by ymmit:
this would be a really useful app where one can advances slides for powerpoint or keynote using his bluetooth phone.

I might have missed it in the previous postings, but is there a script for moving keynote or powerpoint slides backwards and forwards?

It's already built in to the software. No scripts needed. Go forth and remotely control!

[Sal]

SCREEN SAVER SCRIPTS

-- START SCREEN SAVER

Code:
try
	set the target_app to ¬
		((path to "dlib" from System domain as string) & ¬
			"Frameworks:ScreenSaver.framework:Versions:A:Resources:ScreenSaverEngine.app") as alias
	tell application (target_app as string) to launch
on error error_message
	beep
end try

-- STOP SCREEN SAVER

Code:
ignoring application responses
	tell application "ScreenSaverEngine" to quit
end ignoring

[Sal]

Originally posted by ymmit:
this would be a really useful app where one can advances slides for powerpoint or keynote using his bluetooth phone.

I might have missed it in the previous postings, but is there a script for moving keynote or powerpoint slides backwards and forwards?

Here are a couple additional scripts for Keynote. Since the current version of Keynote is not scriptable, they require the installation of the GUI Scripting support, available from here:

www.apple.com/applescript/GUI/

Code:
-- BLACK
try
	tell application "Keynote"
		activate
	end tell
	tell application "System Events"
		tell process "Keynote"
			keystroke "B" with control down
		end tell
	end tell
on error
	beep
end try


-- STOP
try
	tell application "Keynote"
		activate
	end tell
	tell application "System Events"
		tell process "Keynote"
			keystroke "." with command down
		end tell
	end tell
on error
	beep
end try


-- PLAY
try
	tell application "Keynote"
		activate
	end tell
	tell application "System Events"
		tell process "Keynote"
			tell menu bar 1
				click menu item "Play Slideshow" of menu "View"
			end tell
		end tell
	end tell
on error
	beep
end try

[icruise]

I wasn't all that attracted to these phones before, despite their bluetooth connection to iSync/iCal etc, but this sounds really cool. I may have to get one when I move back to the US. The possibilities seem endless!

[Sal]

ITUNES SCRIPT

Toggle Visuals

Requires installation of the GUI scripting support:

www.apple.com/applescript/GUI/

Note that it takes a moment to stop the visual display. Don't click again, it make take 5-10 seconds!

Code:
try
	tell application "iTunes"
		activate
	end tell
	tell application "System Events"
		tell process "iTunes"
			tell menu bar 1
				keystroke "t" with command down
			end tell
		end tell
	end tell
on error
	beep
end try

[iDriveX]

Originally posted by Sal:
SCREEN SAVER SCRIPTS

-- START SCREEN SAVER

Code:
try
	set the target_app to ¬
		((path to "dlib" from System domain as string) & ¬
			"Frameworks:ScreenSaver.framework:Versions:A:Resources:ScreenSaverEngine.app") as alias
	tell application (target_app as string) to launch
on error error_message
	beep
end try

-- STOP SCREEN SAVER

Code:
ignoring application responses
	tell application "ScreenSaverEngine" to quit
end ignoring

The screensaver scripts work great, but they don't work if you've incorporated a password into the screensaver, any way to make a script to quit the screensaverengine with a password?

[iDriveX]

Anyone know how to write a "Next Playlist"/"Previous Playlist" applescript for iTunes? Then my life will be complete.

[drainyoo]

Originally posted by iDriveX:
The screensaver scripts work great, but they don't work if you've incorporated a password into the screensaver, any way to make a script to quit the screensaverengine with a password?

Thats exactly what I need.

Also

Sal do you think you can make me a script so when i come back to my computer it refreshes a page in Safari?

And set na away message in iChat and disable it when I get back.

Thanks!

[Diggory Laycock]

Hmm - perhaps instead of asking Sal to write scripts for you why not look here:

http://www.google.com/search?q=apple...8&oe=UTF-8

[graveguy]

It seems, to me, that one of the most useful applications of the 'proximity' feature would be to turn Address Book's bluetooth feature on...it turns off everytime I walk away from my computer and I have to manually turn it back on every time (ridiculous!)...anyone know if that is scriptable?

I fumbled around with it a bit today but couldn't get this to work...If some applescripter out there knows how, please post!

[Mithras]

Originally posted by iDriveX:
The screensaver scripts work great, but they don't work if you've incorporated a password into the screensaver, any way to make a script to quit the screensaverengine with a password?

Try this for the "approach" script:

Code:
do shell script "kill `ps axww | awk '/ScreenSaverEngine/ {print $1}' | head`"

which will kill the screensaver when you approach, even if you have the screensaver password enabled.

For the "leaving proximity", try this (from someone on Slashdot):

Code:
set previousState to do shell script "defaults -currentHost read com.apple.screensaver askForPassword " 
do shell script "defaults -currentHost write com.apple.screensaver askForPassword 1" 
tell application "ScreenSaverEngine" to run 
do shell script "defaults -currentHost write com.apple.screensaver askForPassword " & previousState

which will start up the screensaver with password required. (but leave in place a previous setting, if you don't want the screensaver to require the password when you're just sitting at the computer)

[iDriveX]

That totally works! I was wondering how to incorporate a shell script into an Apple Script. That's awesome.

Now if someone would just teach me how to go to "Next Playlist" and "Previous Playlist" in iTunes!

[chris v]

I think Vreeland Graphics is about to buy its president a T68i.

The proximity ideas are endless.

Is there a good central database of scripts for this on the web yet? Some kind person should compile them on a page.

CV

[gregpins]

This is all well and good, a nifty little feature. But when will Apple extend Bluetooth and iSync support to a wider set of phones? My phone (a Motorola V60) is provided by my company which uses Verizon, which doesn't offer the T68.

Moreover, I don't use Address Book. It's far too limited for professional use.

Just wish I could take advantage of these techologies.

[Sal]

Originally posted by chris v:
I think Vreeland Graphics is about to buy its president a T68i.

The proximity ideas are endless.

Is there a good central database of scripts for this on the web yet? Some kind person should compile them on a page.

CV

Here are all the scripts I've posted so far. Some of these require installation of the GUI scripting support located at:

www.apple.com/applescript/GUI/

Phone Scripts for: iTunes, Keynote, iPhoto, System

Code:
--- ITUNES SCRIPTS

-- PLAY
tell application "iTunes"
	play
end tell

-- PAUSE
tell application "iTunes"
	pause
end tell

-- STOP
tell application "iTunes"
	stop
end tell

-- REWIND
tell application "iTunes"
	try
		set this_track to the current track
		get this_track
		set the player position to 0
	on error -- no track is the current track
		beep
	end try
end tell

-- VOLUME DOWN
tell application "iTunes"
	set the volume_setting to the sound volume
	if the volume_setting is greater than 10 then
		set the sound volume to (the volume_setting - 10)
	else if the volume_setting is 0 then
		beep
	else
		set the sound volume to 0
	end if
end tell

-- VOLUME UP
tell application "iTunes"
	set the volume_setting to the sound volume
	if the volume_setting is less than 90 then
		set the sound volume to (the volume_setting + 10)
	else if the volume_setting is 100 then
		beep
	else
		set the sound volume to 100
	end if
end tell

-- PREVIOUS TRACK
tell application "iTunes"
	previous track
end tell

-- NEXT TRACK
tell application "iTunes"
	next track
end tell

-- RANDOM TRACK FROM TOP 25
tell application "iTunes"
	stop
	set this_track to some track of playlist "Top 25 Most Played"
	play this_track
end tell

-- TITLE OF THE CURRENT TRACK
tell application "iTunes"
	set this_playlist to the name of current playlist
	set this_track to the name of the current track
	set the player_state to the player state
	pause
	delay 1
end tell
say ("The current song, [[emph-]]is " & this_track & ¬
	 ": of playlist: " & this_playlist) as string
delay 1
tell application "iTunes"
	if the player_state is playing then
		play
	end if
end tell

-- PLAY RANDOM TRACK
tell application "iTunes"
	tell source "Library"
		tell playlist "Library"
			set this_track to some track
			play this_track
		end tell
	end tell
end tell

-- ACTIVATE
tell application "iTunes"
	activate
end tell

-- TOGGLE VISUALS

try
	tell application "iTunes"
		activate
	end tell
	tell application "System Events"
		tell process "iTunes"
			tell menu bar 1
				keystroke "t" with command down
			end tell
		end tell
	end tell
on error
	beep
end try


------- KEYNOTE -------------

-- BLACK
try
	tell application "Keynote"
		activate
	end tell
	tell application "System Events"
		tell process "Keynote"
			keystroke "B" with control down
		end tell
	end tell
on error
	beep
end try


-- STOP
try
	tell application "Keynote"
		activate
	end tell
	tell application "System Events"
		tell process "Keynote"
			keystroke "." with command down
		end tell
	end tell
on error
	beep
end try


-- PLAY
try
	tell application "Keynote"
		activate
	end tell
	tell application "System Events"
		tell process "Keynote"
			tell menu bar 1
				click menu item "Play Slideshow" of menu "View"
			end tell
		end tell
	end tell
on error
	beep
end try


--------- IPHOTO -------------


-- STOP SLIDESHOW
try
	tell application "iPhoto"
		activate
	end tell
	tell application "System Events"
		tell process "iPhoto"
			keystroke "." with control down
		end tell
	end tell
on error
	beep
end try

-- PLAY SLIDESHOW
try
	tell application "iPhoto"
		activate
	end tell
	tell application "System Events"
		tell process "iPhoto"
			-- click the slideshow button
			click button "Slideshow" of list 1 of group 2 of window "iPhoto"
			-- set the slideshow parameters
			tell window "Slideshow Settings"
				-- number of seconds per image
				set the value of text field 1 to "3"
				-- turn off random order
				if value of check box 2 is 1 then click check box 2
				-- turn off repeat
				if value of check box 1 is 1 then click check box 1
				-- turn off music
				if value of check box "Music" of group 1 is 1 then click check box "Music" of group 1
				-- play the slideshow
				click button "Play Slideshow"
			end tell
		end tell
	end tell
on error error_message
	beep
end try


-- NEXT ALBUM
try
	tell application "iPhoto"
		activate
		set these_albums to {"Photo Library", "Last Import"} & the name of every album
		set the album_count to the count of these_albums
		set this_name to the name of the current album
		repeat with i from 1 to the album_count
			if item i of these_albums is this_name then
				set this_index to i
				exit repeat
			end if
		end repeat
		if this_index is the album_count then
			set the next_index to 1
		else
			set the next_index to this_index + 1
		end if
		set the next_album to item next_index of these_albums
		if the next_album is "Photo Library" then
			select photo library album
		else if the next_album is "Last Import" then
			select last import album
		else
			select album next_album
		end if
	end tell
	say next_album as string
end try


--- PREVIOUS ALBUM
try
	tell application "iPhoto"
		activate
		set these_albums to {"Photo Library", "Last Import"} & the name of every album
		set the album_count to the count of these_albums
		set this_name to the name of the current album
		repeat with i from 1 to the album_count
			if item i of these_albums is this_name then
				set this_index to i
				exit repeat
			end if
		end repeat
		if this_index is 1 then
			set the next_index to album_count
		else
			set the next_index to this_index - 1
		end if
		set the next_album to item next_index of these_albums
		if the next_album is "Photo Library" then
			select photo library album
		else if the next_album is "Last Import" then
			select last import album
		else
			select album next_album
		end if
	end tell
	say next_album as string
end try


----------- SYSTEM ----------------

-- SCREEN CAPTURE

set the destination_folder to (path to "pdoc")
set the destination_path to POSIX path of the destination_folder
try
	repeat with i from 1 to 10000
		set the file_name to ("screen" & (i as string) & ".pdf")
		alias ((destination_folder as string) & file_name)
	end repeat
on error
	set the target_path to the destination_path & the file_name
end try
do shell script ("screencapture " & target_path)
beep 2


-- SCREEN SAVER ON

try
	set the target_app to ((path to "dlib" from System domain as string) & "Frameworks:ScreenSaver.framework:Versions:A:Resources:ScreenSaverEngine.app") as alias
	tell application (target_app as string) to launch
on error error_message
	beep
end try

-- SCREEN SAVER OFF

ignoring application responses
	tell application "ScreenSaverEngine" to quit
end ignoring

[iDriveX]

Please Sal, help a newbie AppleScripter out...Just Next Playlist and Previous Playlist! My life will then be complete and I will have full control of iTunes from my phone!