[tikki]

I set up an OS X Server to act as an archive for a bunch of photoshop, quark, illustrator, video, etc. The files are currently archived on a WindowsNT 4 Server that is also the web server.

The files all copies from webserver over to artserver with no perceived complications. However, none of the Mac resource fork information traveled over there. That means when one of the folks upstairs browses a folder to open a quark document, all the documents look like text. No nice Mac icons. Double click on an item and it won't open unless it has an extension the Mac can recognize (ie. PDF).

_Every file in every folder looks like a ****in text document. No icons.

_There's a bunch of Quark files (named filename.qx) that Quark doesn't even see. I had an artist rename a file .QXD and she was able to open it in Quark just fine. However, that is not the type of solution I was looking for.

_The frickken files appear normally to the macs if you look at them on the WinBlows Webserver.

How do I copy and retain my resource fork? I could stuff all the files, but its GIGS.

Thanks for the help.

[Sal]

The following won't solve your resource fork problem but it can make renaming thousands of nested files an automated task.

Here's the code for an AppleSccript droplet (http://www.apple.com/applescript/gui...gs/sbrt.09.htm) that will dig through all levels of a dragged on folder or folders to find the QuarkXPress documents and add ".xdoc" to their names if they don't already have a name extension.

Save the script in the Script Editor application as an application with Stay Open unchecked. Drag on as many folders of files as you want and go to lunch. When you come back your files will be renamed.

Sal

Code:
-- the list of file types which will be processed 
property type_list : {"XDOC"}

-- This droplet processes both files or folders of files dropped onto the applet 
on open these_items
	repeat with i from 1 to the count of these_items
		set this_item to (item i of these_items)
		set the item_info to info for this_item
		if folder of the item_info is true then
			process_folder(this_item)
		else if (alias of the item_info is false and the file type of the item_info is in the type_list) then
			process_item(this_item)
		end if
	end repeat
end open

-- this sub-routine processes folders 
on process_folder(this_folder)
	set these_items to list folder this_folder without invisibles
	repeat with i from 1 to the count of these_items
		set this_item to alias ((this_folder as text) & (item i of these_items))
		set the item_info to info for this_item
		if folder of the item_info is true then
			process_folder(this_item)
		else if (alias of the item_info is false and the file type of the item_info is in the type_list) then
			process_item(this_item)
		end if
	end repeat
end process_folder

-- this sub-routine processes files 
on process_item(this_item)
	-- NOTE that the variable this_item is a file reference in alias format 
	-- FILE PROCESSING STATEMENTS GOES HERE 
	tell application "Finder"
		if the name extension of this_item is "" then
			set this_name to the name of this_item
			set the new_name to this_name & ".xdoc"
			if not (exists document file new_name of the container of this_item) then
				set the name of this_item to the new_name
			end if
		end if
	end tell
end process_item