Originally posted by brachiator:
How do you give the PDF a unique name? When I print to a pdf to Mail, it is always listed as "print.pdf."
thanks
When this feature was first introudced, someone came up with a modified AppleScript that will ask you to name the file before it is added to the e-mail - hopefully you should just be able to copy paste this below into Script Editor and save it as a compiled script (put it in the /Library/PDF Services/ folder):
on open these_items
try
set this_file to item 1 of these_items
tell application "Finder"
set the file_name to the name of this_file
set the parent_folder to (the container of this_file) as alias
end tell
tell application (path to frontmost application as string)
repeat
display dialog "Enter a name for file:" default answer file_name
set this_name to the text returned of the result
if this_name is not "" then
if this_name does not end with ".pdf" then
set this_name to this_name & ".pdf"
end if
exit repeat
end if
end repeat
end tell
tell application "Finder"
set the name of this_file to this_name
set the target_file to ¬
(document file this_name of the parent_folder) as alias
end tell
tell application "Mail"
set the new_message to ¬
(make new outgoing message with properties ¬
{visible:true, content:" "})
tell the new_message
tell content
make new attachment with properties ¬
{file name:target_file} at ¬
before the first character
end tell
end tell
end tell
on error error_message number error_number
if the error_number is not -128 then
tell application (path to frontmost application as string)
display dialog error_message buttons {"OK"} default button 1
end tell
else
tell application "Finder" to delete parent_folder
end if
end try
end open
Top
