[wildside]

Is this the right place to post this?

I need help with a simple applescript.

I need to copy files from FolderA to FolderB

I need to overwrite files from FolderA if they exist in FolderB and ONLY if they are the same exact date or older.

I have been working on a bash shell script with no avail.

Can anyone help me do this with AppleScript?

thanks

[zombie punk]

Have you looked at automator?

[Rainy Day]

Here’s a brute force way of doing it in Applescript (see notes below):

Code:
(*  Moving files from folder A to B, only if files didn’t exist in B, or are newer than B *)

set theSourcePath to "~/junk/"
set theDestinationPath to "~/junk1/"
tell application "Finder"
	set theSourceFolder to POSIX file (do shell script "echo " & theSourcePath) as alias
	set theDestinationFolder to POSIX file (do shell script "echo " & theDestinationPath) as alias
	repeat with theFile in (the name of every item in folder theSourceFolder) as list
		try
			move file theFile in folder theSourceFolder to folder theDestinationFolder
		on error
			set sourceDate to modification date of file theFile in folder theSourceFolder
			set targetDate to modification date of file theFile in folder theDestinationFolder
			if sourceDate ≥ targetDate then
				move file theFile in folder theSourceFolder to folder theDestinationFolder with replacing
			end if
		end try
	end repeat
end tell

Notes:

• I’m not sure i understand your replacement criteria as you worded it, so you may have to change the inequality to get the desired results.
• I also wasn’t sure if you wanted to copy the files, which is what you said, or move the files. This Applescript moves files. You may want to change those move commands to copy.
• I think there is a more direct way of setting up the path variables, without a do shell script call, but i forgot how to do it and didn’t want to spend a lot of time tracking that down. This way works. Personally i prefer working with Unix file paths, rather than the AppleScript way, but clearly you can do it more directly by using AppleScript path notation.
• The repeat loop moves one file at a time (not very efficient, but it gets the job done)
• The Try statement traps errors; if the file exists in the destination, then the On Error block is executed
• In the On Error block, we examine modification dates. Could be altered to exmine creation dates instead. If the dates are right, then overwrite the exiting file. Also, you might want to perform some other action if the dates are not correct.

In bash, you can find the modification date with:

  GetFileInfo -m junk/foo


Important Note: Be all that as it may, probably the best (and fastest) way to do this, however, is with the CLI tool rsync. It is designed to do just this kind of thing, and you should be able do it all with a single rsync command. But it will take you some time to read the man page and understand the proper way to construct the command (because it has so many options, most of which are just noise for a simple task like this). rsync is designed to sync folders between different computers, but it can work just as effectively between different folders on a single computer.